PatternScale Example

Using Programming Languages other than VBA

Sub Example_PatternScale()
	' This example creates an associative hatch in model space.
	' The scale of the hatch pattern is then returned and changed.

	Dim hatchObj As AcadHatch
	Dim patternName As String
	Dim PatternType As Long
	Dim bAssociativity As Boolean

	' Define the hatch
	patternName = "ANSI31"
	PatternType = 0
	bAssociativity = True

	' Create the associative Hatch object
	Set hatchObj = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)

	' Create the outer loop for the hatch.
	' An arc and a line are used to create a closed loop.
	Dim outerLoop(0 To 1) As AcadEntity
	Dim center(0 To 2) As Double
	Dim radius As Double
	Dim startAngle As Double
	Dim endAngle As Double
	center(0) = 5: center(1) = 3: center(2) = 0
	radius = 3
	startAngle = 0
	endAngle = 3.141592
	Set outerLoop(0) = ThisDrawing.ModelSpace.AddArc(center, radius, startAngle, endAngle)
	Set outerLoop(1) = ThisDrawing.ModelSpace.AddLine(outerLoop(0).startPoint, outerLoop(0).endPoint)
	' Append the outer loop to the hatch object
	hatchObj.AppendOuterLoop (outerLoop)

	' Append the first circle as one inner loop
	Dim innerLoop1(0) As AcadEntity
	center(0) = 5: center(1) = 4.5: center(2) = 0
	radius = 1
	Set innerLoop1(0) = ThisDrawing.ModelSpace.AddCircle(center, radius)
	hatchObj.AppendInnerLoop (innerLoop1)

	' Append the second circle as the other inner loop
	Dim innerLoop2(0) As AcadEntity
	radius = 0.5
	Set innerLoop2(0) = ThisDrawing.ModelSpace.AddCircle(center, radius)
	hatchObj.AppendInnerLoop (innerLoop2)

	' Evaluate and display the hatch
	ThisDrawing.Regen True

	' Find the scale of the hatch pattern
	Dim PatternScale As Double
	PatternScale = hatchObj.PatternScale
	MsgBox "The scale of the hatch pattern is " & hatchObj.PatternScale, , "PatternScale Example"
	' Change the scale of the hatch pattern
	hatchObj.PatternScale = PatternScale + 2
	ThisDrawing.Regen True
	MsgBox "The scale of the hatch pattern is now " & hatchObj.PatternScale, , "PatternScale Example"

End Sub