Using Programming Languages other than VBA

Sub Example_ObjectIDToObject()
	' This example creates a spline in model space, and returns the
	' handle for the spline. Then the spline is returned from the handle and colored.

	' Create the spline
	Dim splineObj As AcadSpline
	Dim startTan(0 To 2) As Double
	Dim endTan(0 To 2) As Double
	Dim fitPoints(0 To 8) As Double

	startTan(0) = 0.5: startTan(1) = 0.5: startTan(2) = 0
	endTan(0) = 0.5: endTan(1) = 0.5: endTan(2) = 0
	fitPoints(0) = 1: fitPoints(1) = 1: fitPoints(2) = 0
	fitPoints(3) = 5: fitPoints(4) = 5: fitPoints(5) = 0
	fitPoints(6) = 10: fitPoints(7) = 0: fitPoints(8) = 0
	Set splineObj = ThisDrawing.ModelSpace.AddSpline(fitPoints, startTan, endTan)

	ZoomAll

	' Find the objectID of the spline
	Dim objectID As Long
	objectID = splineObj.objectID
	MsgBox "The objectID of the Spline is: " & splineObj.objectID, , "ObjectIDToObject Example"
	
	' Find an object from a given objectID
	Dim tempObj As AcadObject
	Set tempObj = ThisDrawing.ObjectIdToObject(objectID)

	' Now use the newly initialized object variable to color the object 
	Dim color As AcadAcCmColor
	Set color = AcadApplication.GetInterfaceObject("AutoCAD.AcCmColor.16")
	Call color.SetRGB(80, 100, 244)

	tempObj.TrueColor = color

	ThisDrawing.Regen True
	MsgBox "The Spline is now blue.", , "ObjectIDToObject Example"

End Sub